AI 助理
备案控制台
文档
输入文档关键字查找
首页 配置审计 开发参考 使用Terraform创建一个投递渠道

使用Terraform创建一个投递渠道

更新时间：
产品详情
我的收藏

Terraform是一种开源工具，用于安全高效地预配和管理云基础结构。您可以使用Terraform管理配置审计资源。本文为您介绍如何通过Terraform创建一个配置审计的投递渠道。

说明

当前示例代码支持一键运行，您可以直接运行代码。一键运行

前提条件

  • 由于阿里云账号（主账号）具有资源的所有权限，一旦发生泄露将面临重大风险。建议您使用RAM用户，并为该RAM用户创建AccessKey，具体操作方式，请参见创建RAM用户和创建AccessKey。

  • 使用以下示例为RAM用户授权，需要为该RAM用户授予以下权限：管理配置审计资源AliyunConfigFullAccess的权限。具体操作方式，请参见为RAM用户授权。

    {
    "Version": "1",
    "Statement": [
        {
            "Action": [
                "config:*"
            ],
            "Resource": "*",
            "Effect": "Allow"
        },
        {
            "Action": "ram:CreateServiceLinkedRole",
            "Resource": "*",
            "Effect": "Allow",
            "Condition": {
                "StringEquals": {
                    "ram:ServiceName": "config.aliyuncs.com"
                }
            }
        }
    ]
}

  • 准备Terraform运行环境，您可以选择以下任一方式来使用Terraform。

    在Terraform Explorer中使用Terraform：阿里云提供了Terraform的在线运行环境，您无需安装Terraform，登录后即可在线使用和体验Terraform。适用于零成本、快速、便捷地体验和调试Terraform的场景。

    Cloud Shell：阿里云Cloud Shell中预装了Terraform的组件，并已配置好身份凭证，您可直接在Cloud Shell中运行Terraform的命令。适用于低成本、快速、便捷地访问和使用Terraform的场景。

    在本地安装和配置Terraform：适用于网络连接较差或需要自定义开发环境的场景。

重要

请确保Terraform版本不低于v0.12.28。如需检查现有版本，请运行terraform --version命令。

使用的资源

alicloud_config_delivery：创建一个投递渠道。

使用Terraform创建一个投递渠道

本示例将创建一个投递渠道。

  1. 创建一个工作目录，并且在工作目录中创建以下名为main.tf的配置文件。main.tf是Terraform主文件，定义了将要部署的资源。

    variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
variable "name" {
  default = "tf-example-sls"
}
variable "description" {
  default = "terraform-example"
}
# 获取当前用户uid
data "alicloud_account" "this" {}
# 获取区域信息
data "alicloud_regions" "this" {
  current = true
}
# 随机数
resource "random_integer" "default" {
  max = 99999
  min = 10000
}
#  创建SLS 项目资源
resource "alicloud_log_project" "default" {
  # 描述
  description  = var.description
  # 名称
  project_name = "${var.name}-${random_integer.default.result}"
}
# 创建SLS日志存储资源
resource "alicloud_log_store" "default" {
  # 名称
  logstore_name    = var.name
  #（可选，强制新建，自 v1.215.0 起可用）该日志存储所属的项目名称。
  project_name = alicloud_log_project.default.project_name
  # （可选，强制新建，计算得出，整数）该日志存储中的分片数量。默认为 2。
  shard_count           = 2
  # （可选）决定是否自动拆分分片。默认为 false。
  auto_split            = true
  # （可选，整数）自动拆分的最大分片数，范围为 1 到 256。
  max_split_shard_count = 60
  # （可选，计算得出）决定是否自动附加日志元数据。元数据包括日志接收时间和客户端 IP 地址。默认为 true。
  append_meta           = true
  # （可选，计算得出，整数）数据保留时间（以天为单位）。有效值：[1-3650]。
  retention_period      = 30
}
# 创建投递渠道
resource "alicloud_config_delivery" "default" {
  # （可选）指示指定的目标是否接收资源更改日志。如果该值为 true
  configuration_item_change_notification = true
  # （可选）指示指定的目标是否接收资源不合规事件
  non_compliant_notification             = true
  # （可选）交付通道的名称
  delivery_channel_name                  = var.name
  # （必需）交付目标的 ARN
  delivery_channel_target_arn            = "acs:log:${data.alicloud_regions.this.ids.0}:${data.alicloud_account.this.id}:project/${alicloud_log_project.default.project_name}/logstore/${alicloud_log_store.default.logstore_name}"
  # （必需，强制新建）交付通道的类型
  delivery_channel_type                  = "SLS"
  # 描述
  description                            = var.description
  # 状态0：交付通道已禁用，1：交付通道已启用。
  status                                 = 1
}

  2. 执行以下命令，初始化Terraform运行环境。

    terraform init

    返回如下信息，表示Terraform初始化成功。

    Initializing the backend...

Initializing provider plugins...
- Finding latest version of hashicorp/alicloud...
- Installing hashicorp/alicloud v1.234.0...
- Installed hashicorp/alicloud v1.234.0 (signed by HashiCorp)

Terraform has created a lock file .terraform.lock.hcl to record the provider
selections it made above. Include this file in your version control repository
so that Terraform can guarantee to make the same selections by default when
you run "terraform init" in the future.

Terraform has been successfully initialized!

You may now begin working with Terraform. Try running "terraform plan" to see
any changes that are required for your infrastructure. All Terraform commands
should now work.

If you ever set or change modules or backend configuration for Terraform,
rerun this command to reinitialize your working directory. If you forget, other
commands will detect it and remind you to do so if necessary.

  3. 创建执行计划，并预览变更。

    terraform plan

  4. 执行以下命令，创建一个投递渠道。

    terraform apply

    在执行过程中，根据提示输入yes并按下Enter键，等待命令执行完成，若出现以下信息，则表示创建一个投递渠道成功。

    Plan: 4 to add, 0 to change, 0 to destroy.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

random_integer.default: Creating...
random_integer.default: Creation complete after 0s [id=5****]
alicloud_log_project.default: Creating...
alicloud_log_project.default: Creation complete after 0s [id=tf-example-sls-5****]
alicloud_log_store.default: Creating...
alicloud_log_store.default: Creation complete after 0s [id=tf-example-sls-54000:tf-examp****]
alicloud_config_delivery.default: Creating...
alicloud_config_delivery.default: Creation complete after 1s [id=cdc-fd984fbef2bc0099****]

Apply complete! Resources: 4 added, 0 changed, 0 destroyed.

  5. 验证结果 。

    执行terraform show命令

    您可以使用以下命令查询Terraform已创建的资源详细信息：

    terraform show

    image

    登录配置审计控制台

    创建完成后，您可以通过OpenAPI、SDK或者配置审计控制台等方式，检查操作是否正确完成。image

清理资源

当您不再需要上述通过Terraform创建或管理的资源时，请运行以下命令以释放资源。关于terraform destroy的更多信息，请参见Terraform常用命令。

terraform destroy

完整示例

说明

当前示例代码支持一键运行，您可以直接运行代码。一键运行

示例代码

variable "region" {
  default = "cn-heyuan"
}
provider "alicloud" {
  region = var.region
}
variable "name" {
  default = "tf-example-sls"
}
variable "description" {
  default = "terraform-example"
}
# 获取当前用户uid
data "alicloud_account" "this" {}
# 获取区域信息
data "alicloud_regions" "this" {
  current = true
}
# 随机数
resource "random_integer" "default" {
  max = 99999
  min = 10000
}
#  创建SLS 项目资源
resource "alicloud_log_project" "default" {
  # 描述
  description  = var.description
  # 名称
  project_name = "${var.name}-${random_integer.default.result}"
}
# 创建SLS日志存储资源
resource "alicloud_log_store" "default" {
  # 名称
  logstore_name    = var.name
  #（可选，强制新建，自 v1.215.0 起可用）该日志存储所属的项目名称。
  project_name = alicloud_log_project.default.project_name
  # （可选，强制新建，计算得出，整数）该日志存储中的分片数量。默认为 2。
  shard_count           = 2
  # （可选）决定是否自动拆分分片。默认为 false。
  auto_split            = true
  # （可选，整数）自动拆分的最大分片数，范围为 1 到 256。
  max_split_shard_count = 60
  # （可选，计算得出）决定是否自动附加日志元数据。元数据包括日志接收时间和客户端 IP 地址。默认为 true。
  append_meta           = true
  # （可选，计算得出，整数）数据保留时间（以天为单位）。有效值：[1-3650]。
  retention_period      = 30
}
# 创建投递渠道
resource "alicloud_config_delivery" "default" {
  # （可选）指示指定的目标是否接收资源更改日志。如果该值为 true
  configuration_item_change_notification = true
  # （可选）指示指定的目标是否接收资源不合规事件
  non_compliant_notification             = true
  # （可选）交付通道的名称
  delivery_channel_name                  = var.name
  # （必需）交付目标的 ARN
  delivery_channel_target_arn            = "acs:log:${data.alicloud_regions.this.ids.0}:${data.alicloud_account.this.id}:project/${alicloud_log_project.default.project_name}/logstore/${alicloud_log_store.default.logstore_name}"
  # （必需，强制新建）交付通道的类型
  delivery_channel_type                  = "SLS"
  # 描述
  description                            = var.description
  # 状态0：交付通道已禁用，1：交付通道已启用。
  status                                 = 1
}

如果您想体验更多完整示例，请前往更多完整示例中对应产品的文件夹查看。

上一篇：CLI集成示例下一篇：服务支持